Terraform ile Gyro Bulut sunucusu: sağlayıcı kurulumu ve ilk apply

1. Sağlayıcı hakkında

Gyro'nun resmi Terraform sağlayıcısı Terraform Registry'de gyro-hosting/gyro adıyla yayındadır (bu rehber yazılırken sürüm 0.2.1). Gyro Public API'yi kullanır; panelde yaptığınız işleri kodla tanımlamanızı sağlar.

Bu rehber bulut sunucu üzerinden temel akışı anlatır; diğer kaynakların belgeleri Registry sayfasında.

2. API anahtarını hazırlama

1. Müşteri panelinde hesap menüsünden API Kimlik Bilgileri'ni açın ve Terraform için ayrı bir anahtar oluşturun (Gyro API'ye ilk adım).

2. İzinler: cloud_read, cloud_write, cloud_order (sunucu açmak için), cloud_delete (sunucu silmek için).

3. Anahtarı ortam değişkenine koyun; .tf dosyasına yazmayın:

   bash

   read -rs GYRO_TOKEN && export GYRO_TOKEN
   

Sağlayıcı anahtarı GYRO_TOKEN değişkeninden okur. CI'da (GitHub Actions, GitLab CI) aynı adı taşıyan bir gizli değişken tanımlayın.

3. Yapılandırma dosyası

Boş bir klasörde main.tf oluşturun:

terraform {
  required_providers {
    gyro = {
      source  = "gyro-hosting/gyro"
      version = "~> 0.3"
    }
  }
}

# Anahtarı GYRO_TOKEN ortam değişkeninden okur.
provider "gyro" {}

resource "gyro_ssh_key" "laptop" {
  name       = "laptop"
  public_key = file("~/.ssh/id_ed25519.pub")
}

resource "gyro_server" "web" {
  plan          = "standart-2-4"     # Gyro Bulut Standart 2 vCPU / 4 GB
  region        = "eu-de-1"          # Almanya (Falkenstein)
  cycle         = "monthly"
  image         = "ubuntu-24.04"
  hostname      = "web-1.ornekfirma.com"
  ssh_key_ids   = [tonumber(gyro_ssh_key.laptop.id)]
  power_state   = "running"
  confirm_order = true               # sunucu oluşturmak bakiyeden ödenen bir siparişdir
}

output "web_ipv4" {
  value = gyro_server.web.ipv4
}

Hangi plan ve region?

plan paketi (ör. standart-2-4), region lokasyonu belirler. Bölgeler: eu-de-1 Falkenstein, eu-de-2 Nürnberg, eu-fi-1 Helsinki, us-east-1 Ashburn, us-west-1 Hillsboro, ap-sg-1 Singapur. İsterseniz plan+region yerine tek bir ürün numarası da verebilirsiniz (product_id; sitede paketin Başlayın düğmesinin açtığı sipariş adresindeki sayı, ör. …/siparis/server/814).

Sürüm 0.2 kullanıyorsanız: 0.3'e geçmek mevcut sunucuları yeniden oluşturmaz. Eski server_type/location alanları çalışır ama uyarı verir; yeni yapılandırmalarda plan/region kullanın.

Tüm satıştaki paketleri Terraform'dan da listeleyebilirsiniz. Şu bloğu ekleyip terraform plan çalıştırın:

data "gyro_locations" "tum" {}

data "gyro_products" "tum" {
  available_only = true
}

locals {
  sehir = { for l in data.gyro_locations.tum.locations : l.region => l.city }
}

output "paketler" {
  value = [for p in data.gyro_products.tum.products :
    "${p.plan}  ${p.region}  ${local.sehir[p.region]}  ${p.monthly_price} ${p.currency}"]
}

Çıktı her paketi plan adı, bölgesi, şehri ve aylık fiyatıyla verir; istediğinizi plan ve region'a yazın.

gyro_server alanları

Okunabilen alanlar: id (paneldeki hizmet numarası), ipv4, ipv6_network, cores, memory_gb, disk_gb, status, price, currency, due_date.

4. plan ve apply

terraform init      # sağlayıcıyı indirir
terraform plan      # ne yapılacağını gösterir, hiçbir şey oluşturmaz
terraform apply     # onayınızdan sonra siparişi verir ve sunucu hazır olana kadar bekler

apply sırasında Terraform sunucunun durumunu belirli aralıklarla sorgular; sunucu çalışır hale gelince IP adresini çıktı olarak verir:

Outputs:
web_ipv4 = "203.0.113.10"

Ardından ssh [email protected] ile bağlanabilirsiniz. Sunucu müşteri panelinde de Hizmetlerim altında görünür.

Değişiklik yapmak

• hostname, power_state ve auto_renew değişikliği sunucuyu silmeden, yerinde uygulanır.
• plan, region (ya da product_id), image, cycle, ssh_key_ids ya da user_data değişikliği sunucuyu silip yeniden oluşturur; bu, yeni bir sipariş ve eski sunucudaki verinin kaybı demektir. plan çıktısında must be replaced görürseniz durun ve kontrol edin.
• Paketi verinizi koruyarak büyütmek için plan'ı değiştirmeyin; panelden Yükseltme/Düşürme sekmesini kullanın, ardından .tf dosyasındaki plan'ı yeni paketle güncelleyin.

5. Panelden açtığınız sunucuyu Terraform'a almak

Var olan bir sunucuyu yeniden oluşturmadan Terraform yönetimine alabilirsiniz:

1. main.tf içine sunucuyu tanımlayan bir gyro_server bloğu yazın (plan, region, image mevcut sunucuyla aynı olmalı).

2. Paneldeki hizmet numarasıyla içe aktarın:

   bash

   terraform import gyro_server.web 47466
   

3. terraform plan çalıştırın; değişiklik görünmüyorsa tanım ve sunucu eşleşmiştir.

SSH anahtarları da aynı yolla alınır: terraform import gyro_ssh_key.laptop <anahtar-no>.

6. destroy ne yapar?

Hemen iptal yerine bir iptal talebi açılmasını istiyorsanız kaynağa delete_immediately = false ekleyin; bu durumda talep işlenene kadar sunucu çalışmaya ve faturalanmaya devam eder.

Üretim sunucularını yanlışlıkla silmemek için Terraform'un kendi korumasını kullanın:

resource "gyro_server" "db" {
  # ...
  lifecycle {
    prevent_destroy = true
  }
}

7. Sorun giderme

8. Sık sorulan sorular